# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

inherit vdr-plugin

DESCRIPTION="Video Disk Recorder last.fm PlugIn"
HOMEPAGE="http://sourceforge.net/projects/vdr-lastfm/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tgz"

KEYWORDS="~x86"
SLOT="0"
LICENSE="GPL-2"
IUSE="imlib2 imagemagick softdevice"

DEPEND=">=media-video/vdr-1.4.0 >=media-libs/libmad-0.15.1b
	>=dev-libs/sockets-2.2.0
	imlib2?      ( >=media-libs/imlib2-1.2.1 )
	imagemagick? ( media-gfx/imagemagick )
	softdevice?  ( media-plugins/vdr-softdevice media-video/ffmpeg )"

pkg_setup() {
	if use imlib2 && use imagemagick
	then
		eerror "USE=imlib2 and USE=imagemagick cannot be active at the same"
		eerror "time."
		die "useflag conflict"
	fi
	vdr-plugin_pkg_setup
}

src_unpack() {
	vdr-plugin_src_unpack

	einfo "Configuring plugin"
	use softdevice && sed -i Makefile -e '2i\LASTFM_USE_SOFTDEVICE_RECEIVER=1'
	use imagemagick && sed -i Makefile -e '2i\LASTFM_HAVE_MAGICK=1'

	if use imlib2
	then
		ewarn "USE=imlib2 is considered experimental and incomplete currently,"
		ewarn "try USE=imagemagick instead."
		echo
		sed -i Makefile -e '2i\HAVE_IMLIB2=1'
	fi
}

pkg_postinst() {
	einfo "If you are upgrading from vdr-lastfm-0.1.x you may want to migrate"
	einfo "your settings and favorites from vdr-lastfm-0.1.x to the new version."
	einfo "See 'vdr --help' to accomplish that."
	echo
}